You are reading without signing in. Sign in or continue as guest to take quizzes and climb the ranks.
Teleportation with feed-forward
The protocol that needs dynamic circuits: two classical bits move one qubit of state.
- 01Explain each of the four stages of teleportation.
- 02Say why the two classical bits are necessary (no faster-than-light signalling).
- 03Verify the protocol with a measurement in the right basis.
- 1. Share a Bell pair between q1 (sender) and q2 (receiver).
- 2. The sender entangles the message qubit q0 with q1: CNOT then H.
- 3. Measure q0 and q1: two classical bits.
- 4. The receiver applies X if c[1] = 1 and Z if c[0] = 1. q2 now carries the original state.
Teleport ry(0.6)|0⟩
The last gate undoes the preparation on q2, so a perfect teleport always reads c[2] = 0. Simulate: the last bit is 0 in every shot. Remove either correction and it is no longer.
OPENQASM 3.0;
include "stdgates.inc";
qubit[3] q;
bit[3] c;
ry(0.6) q[0];
h q[1];
cx q[1], q[2];
cx q[0], q[1];
h q[0];
c[0] = measure q[0];
c[1] = measure q[1];
if (c[1] == true) {
x q[2];
}
if (c[0] == true) {
z q[2];
}
ry(-0.6) q[2];
c[2] = measure q[2];
Before the corrections, q2 is in one of four states depending on the two bits: the message, or the message with an X, a Z, or both applied. Without the bits the receiver sees a completely mixed qubit; nothing about the message has travelled. The bits travel classically, so no information moves faster than light.
2 questions · one try each counts
What has the receiver before the two classical bits arrive?
Sign in to answer and climb the ranks; you will come back to this lesson.
Teleportation is also written with deferred measurement (CX/CZ corrections, no if). Why prefer the dynamic version on hardware?
Sign in to answer and climb the ranks; you will come back to this lesson.